vulkan: add support for blend buffers

src/gfx_apis/vulkan/shaders/frag_spec_const.glsl

@@ -1,2 +1,8 @@
+#ifndef FRAG_SPEC_CONST_GLSL
+#define FRAG_SPEC_CONST_GLSL
+
 layout(constant_id = 0) const bool src_has_alpha = false;
 layout(constant_id = 1) const bool has_alpha_multiplier = false;
+layout(constant_id = 2) const bool color_management = false;
+
+#endif

src/gfx_apis/vulkan/shaders/out.common.glsl

@@ -0,0 +1,3 @@
+layout(push_constant, std430) uniform Data {
+	layout(offset = 0) vec2 pos[4];
+} data;

src/gfx_apis/vulkan/shaders/out.frag

@@ -0,0 +1,17 @@
+#version 450
+#extension GL_EXT_samplerless_texture_functions : require
+
+#include "frag_spec_const.glsl"
+#include "transfer_functions.glsl"
+#include "out.common.glsl"
+
+layout(set = 0, binding = 0) uniform texture2D in_color;
+layout(location = 0) out vec4 out_color;
+
+void main() {
+	vec4 c = texelFetch(in_color, ivec2(gl_FragCoord.xy), 0);
+	c.rgb /= mix(c.a, 1.0, c.a == 0.0);
+	c.rgb = oetf_srgb(c.rgb);
+	c.rgb *= c.a;
+	out_color = c;
+}

src/gfx_apis/vulkan/shaders/out.vert

@@ -0,0 +1,16 @@
+#version 450
+//#extension GL_EXT_debug_printf : enable
+
+#include "out.common.glsl"
+
+void main() {
+	vec2 pos;
+	switch (gl_VertexIndex) {
+		case 0: pos = data.pos[0]; break;
+		case 1: pos = data.pos[1]; break;
+		case 2: pos = data.pos[2]; break;
+		case 3: pos = data.pos[3]; break;
+	}
+	gl_Position = vec4(pos, 0.0, 1.0);
+//	debugPrintfEXT("X gl_Position = %v4f, pos = %v2f", gl_Position, pos);
+}

src/gfx_apis/vulkan/shaders/tex.frag

@@ -1,6 +1,7 @@
 #version 450
 
 #include "frag_spec_const.glsl"
+#include "transfer_functions.glsl"
 #include "tex.common.glsl"
 
 layout(set = 0, binding = 0) uniform sampler2D tex;
@@ -8,13 +9,22 @@ layout(location = 0) in vec2 tex_pos;
 layout(location = 0) out vec4 out_color;
 
 void main() {
+	vec4 c = textureLod(tex, tex_pos, 0);
+	if (color_management) {
+		if (src_has_alpha) {
+			c.rgb /= mix(c.a, 1.0, c.a == 0.0);
+		}
+		c.rgb = eotf_srgb(c.rgb);
+		if (src_has_alpha) {
+			c.rgb *= c.a;
+		}
+	}
 	if (has_alpha_multiplier) {
 		if (src_has_alpha) {
-			out_color = textureLod(tex, tex_pos, 0) * data.mul;
+			c *= data.mul;
 		} else {
-			out_color = vec4(textureLod(tex, tex_pos, 0).rgb * data.mul, data.mul);
+			c = vec4(c.rgb * data.mul, data.mul);
 		}
-	} else {
-		out_color = textureLod(tex, tex_pos, 0);
 	}
+	out_color = c;
 }

src/gfx_apis/vulkan/shaders/transfer_functions.glsl

@@ -0,0 +1,21 @@
+#ifndef TRANSFER_FUNCTIONS_GLSL
+#define TRANSFER_FUNCTIONS_GLSL
+
+vec3 eotf_srgb(vec3 c) {
+    return mix(
+        c * vec3(1.0 / 12.92),
+        pow((c + vec3(0.055)) / vec3(1.055), vec3(2.4)),
+        greaterThan(c, vec3(0.04045))
+    );
+}
+
+vec3 oetf_srgb(vec3 c) {
+    c = clamp(c, 0.0, 1.0);
+    return mix(
+        c * vec3(12.92),
+        vec3(1.055) * pow(c, vec3(1/2.4)) - vec3(0.055),
+        greaterThan(c, vec3(0.0031308))
+    );
+}
+
+#endif